DFdou's Blog Life is short,Be yourself.

AS3-aSpaceEscape 迷宫脱离游戏(四)整合部分

前边咱讲了地图和角色的生成以及逻辑代码部分，接下去就是2者的整合了。
这个整合的类我把它命名成Controller.as，在主场景的时间轴里写上：

import org.nwhy.aSpaceEscape.*;
var controller:Controller = new Controller(stage,0);
addChild(controller);

然后是Controller.as：

package org.nwhy.aSpaceEscape{
	import flash.display.Sprite;
	import flash.display.Stage;

	public class Controller extends Sprite{
		private var mStage:Stage;
		public static var level:uint;//等级
		private var role:Role;

		public function Controller(stage:Stage,levelID:uint){
			mStage = stage;
			level = levelID;
			drawMap();
			drawRole();
		}
		private function drawMap(){
			var map:Map = new Map(Config.MAP[level]);
			addChild(map);
		}

		private function drawRole(){
			role = new Role(mStage);
			addChild(role);
		}
	}
}

代码内容很简单，画一个Map，然后画一个Role，就完成了～
整个游戏的代码地址(Full source)：http://dl.dropbox.com/u/477487/flash/game/aSpaceEscape.rar

AS3-aSpaceEscape 迷宫脱离游戏(三)角色部分

刚我们讲了地图，看起来还是挺简单的，只要输入一个数组，或者说是一个地图矩阵块，一个地图就被生成了。
那下边我们无敌的主角就要上场了，就是那个看起来在大笑，那个很嚣张的东东，我们就起个类名叫Role好了，当然你也可以把这个类叫JJ，GG，MM，DD，etc～

跟角色有关的逻辑应该尽量都放在这个类内部，为啥说应该尽量呢，有些时候有变态的特殊需求嘛。
好，来看Role.as：

package org.nwhy.aSpaceEscape{
	import flash.display.Sprite;
	import flash.display.Stage;
	import flash.geom.Rectangle;
	import flash.events.*;

	public class Role extends Sprite {
		private var mStage:Stage;//根场景的stage;
		private var level:uint;
		private var mSpeed:int = Config.TILE_SIZE;//移动速度
		private var xSpeed:int;
		private var ySpeed:int;
		private var mDown:Array = [0,0,0,0];//按键组合,只需要上下左右不需要45度角,so...
		private var isKeyDown:Boolean;

		public function Role(stage:Stage):void {
			level = Controller.level;
			mStage = stage;
			reset();
			//添加事件监听
			addEventListeners();
		}
		private function addEventListeners():void{
			mStage.addEventListener(KeyboardEvent.KEY_DOWN, mKeyDownHandler);//Keyboard事件
			mStage.addEventListener(KeyboardEvent.KEY_UP, mKeyUpHandler);
			addEventListener(Event.ENTER_FRAME, mUpdate);
		}
		private function mKeyDownHandler(e:KeyboardEvent):void{
			if(!isKeyDown){
				switch (e.keyCode) {
					case 37 :
						mDown[0]=1;
						break;
					case 38 :
						mDown[1]=1;
						break;
					case 39 :
						mDown[2]=1;
						break;
					case 40 :
						mDown[3]=1;
					break;
				}
				isKeyDown = true;
			}
			checkKeyDown(mDown.join(""));
		}
		private function mKeyUpHandler(e:KeyboardEvent):void {
			switch (e.keyCode) {
				case 37 :
					mDown[0]=0;
					break;
				case 38 :
					mDown[1]=0;
					break;
				case 39 :
					mDown[2]=0;
					break;
				case 40 :
					mDown[3]=0;
					break;
			}
		}
		private function checkKeyDown(k:String){
			switch(k){
				case "1000" :
					//trace("left");
					xSpeed = - mSpeed;
					ySpeed = 0;
					break;
				case "0100" :
					//trace("top");
					xSpeed = 0;
					ySpeed = - mSpeed;
					break;
				case "0010" :
					//trace("right");
					xSpeed = mSpeed;
					ySpeed = 0;
					break;
				case "0001" :
					//trace("down");
					xSpeed = 0;
					ySpeed = mSpeed;
					break;
			}
		}
		private function mUpdate(e:Event){
			var posX:int = (x+xSpeed)/mSpeed;
			var posY:int = (y+ySpeed)/mSpeed;

			if(posX>=Config.TILE_PERLINE || posY>=Config.TILE_PERLINE || posX< =-1 || posY<=-1){
				trace("out of stage");
				xSpeed = 0;
				ySpeed = 0;
				reset();
				isKeyDown = false;
			}else if(Config.MAP[level][posY][posX] > 1 && Config.MAP[level][posY][posX] !=5){
				xSpeed = 0;
				ySpeed = 0;
				isKeyDown = false;
				//trace(posX,posY,Config.MAP[level][posY][posX]);
			}else if(Config.MAP[level][posY][posX] == 5){
				trace("succ");
				x += xSpeed;
				y += ySpeed;
				xSpeed = 0;
				ySpeed = 0;
			}

			x += xSpeed;
			y += ySpeed;
		}
		private function reset(){
			x = Config.ROLE_POSITION[Controller.level][0] * Config.TILE_SIZE;
			y = Config.ROLE_POSITION[Controller.level][1] * Config.TILE_SIZE;
		}
	}
}