DFdou's Blog Life is short,Be yourself.

Google Maps API for Flash Demo

Google Maps API的ActionScript3版本出来已经有一段时间了，今天在官方文档(里边有很详细的介绍)那看了一下，做了2个Demo，关于中文版的地图…恩，，是没出？还是SDK里可以设置语言？知道的告诉我一下，我是农民，不知道怎么设置。
先是一般的地图，带标记，拖动，和位置查询。


来来，代码：

import com.google.maps.LatLng;
import com.google.maps.Map;
import com.google.maps.MapEvent;
import com.google.maps.MapMouseEvent;
import com.google.maps.MapType;
import com.google.maps.InfoWindowOptions;
import com.google.maps.controls.ZoomControl;
import com.google.maps.controls.PositionControl;
import com.google.maps.overlays.Marker;
import com.google.maps.overlays.MarkerOptions;
import com.google.maps.services.ClientGeocoder;
import com.google.maps.services.GeocodingEvent;

var map:Map = new Map();
map.key = "ABQIAAAAo5RLwGEOxmVA88OUDH7fDRQCv6C133r1XzmkPp8P2SPfybuhnxRC1L3ALirem35g_tUs6uhkINg6xg";//这里输入你的googlemap api key
map.setSize(new Point(stage.stageWidth, stage.stageHeight));//设置map的宽度和高度
map.addEventListener(MapEvent.MAP_READY, onMapReady);
this.addChild(map);
var mc_search=new Search_mc();
mc_search.x=280;
mc_search.y=10;
this.addChild(mc_search);
function onMapReady(_evt:Event):void {
  mc_search.btn_search.addEventListener(MouseEvent.CLICK,doGeocode);
  map.setCenter(new LatLng(30, 115), 5, MapType.NORMAL_MAP_TYPE);
  //map.enableScrollWheelZoom();
  map.addControl(new ZoomControl());
  map.addControl(new PositionControl());
  //map.addControl(new MapTypeControl());
  map.addEventListener(MapMouseEvent.CLICK, onMapClick);
  var marker:Marker = new Marker(map.getCenter(), new MarkerOptions({draggable: true}));
  marker.addEventListener(MapMouseEvent.DRAG_START,dragMarker);
  marker.addEventListener(MapMouseEvent.DRAG_END,dropMarker);
  map.addOverlay(marker);
}
function onMapClick(_evt:MapMouseEvent){
	//map.openInfoWindow(_evt.latLng,new InfoWindowOptions({title: "Click Event", content: "You clicked the map!"}));
}
function dragMarker(_evt:MapMouseEvent):void {
    map.closeInfoWindow();
};
function dropMarker(_evt:MapMouseEvent):void {
    map.openInfoWindow(_evt.latLng,new InfoWindowOptions({content: "Marker was droped here!"}));
};
function doGeocode(event:Event):void {
    var geocoder:ClientGeocoder = new ClientGeocoder();
    geocoder.addEventListener(GeocodingEvent.GEOCODING_SUCCESS,geoSuccess);
    geocoder.addEventListener(GeocodingEvent.GEOCODING_FAILURE,geoFailed);
    geocoder.geocode(mc_search.address.text);
}
function geoSuccess(_evt:GeocodingEvent){
     var placemarks:Array = _evt.response.placemarks;
     if (placemarks.length > 0) {
     	map.setCenter(placemarks[0].point);
     	var marker:Marker = new Marker(placemarks[0].point);
     	marker.addEventListener(MapMouseEvent.CLICK, function (event:MapMouseEvent):void {
     		marker.openInfoWindow(new InfoWindowOptions({content: placemarks[0].address}));
        });
      map.addOverlay(marker);
      }
}
function geoFailed(_evt:GeocodingEvent){
	trace("Geocoding failed");
}

接着是地图导航的部分：

来来，又是代码部分：

import com.google.maps.*;
import com.google.maps.overlays.*;
import com.google.maps.services.*;

var dir:Directions;
var turnCounter:uint = 0;

var map:Map = new Map();
map.key = "ABQIAAAAo5RLwGEOxmVA88OUDH7fDRQCv6C133r1XzmkPp8P2SPfybuhnxRC1L3ALirem35g_tUs6uhkINg6xg";//这里输入你的googlemap api key
map.setSize(new Point(stage.stageWidth, stage.stageHeight));//设置map的宽度和高度
map.addEventListener(MapEvent.MAP_READY, onMapReady);
this.addChild(map);

var mc_input=new MC_input();
this.addChild(mc_input);
mc_input.getTurnByTurnDirections.enabled = false;

function onMapReady(_evt:MapEvent):void {
	map.setCenter(new LatLng(30,115), 5, MapType.NORMAL_MAP_TYPE);
	dir = new Directions();
	dir.addEventListener(DirectionsEvent.DIRECTIONS_SUCCESS, onDirLoad);
	dir.addEventListener(DirectionsEvent.DIRECTIONS_FAILURE, onDirFail);
	mc_input.getDirections.addEventListener(MouseEvent.CLICK, processDirections);
	mc_input.getTurnByTurnDirections.addEventListener(MouseEvent.CLICK, processTurnByTurn);
}

function processDirections(_evt:Event):void {
	dir.load("from: " + mc_input.from.text + " to: " + mc_input.to.text);
	mc_input.getTurnByTurnDirections.enabled = true;

	// Reset turnCounter to zero for new directions
	turnCounter = 0;
	mc_input.step.htmlText = "Start at " + mc_input.from.text;
}

function onDirFail(_evt:DirectionsEvent):void {
	mc_input.step.htmlText = "onDirFail";
}

function onDirLoad(_evt:DirectionsEvent):void {
	var dir:Directions = _evt.directions;
	var startMarker:Marker;
	var endMarker:Marker;

	map.clearOverlays();
	map.addOverlay(dir.createPolyline());
	map.setZoom(map.getBoundsZoomLevel(dir.bounds));
	map.setCenter(dir.bounds.getCenter());

	startMarker = new Marker(dir.getRoute(0).startGeocode.point, new MarkerOptions({fillStyle: {color:Color.GREEN}}));
	endMarker = new Marker(dir.getRoute(0).endGeocode.point, new MarkerOptions({fillStyle: {color:Color.BLUE}}));
	map.addOverlay(startMarker);
	map.addOverlay(endMarker);
}

function processTurnByTurn(_evt:Event):void {
	var stepText:String;
	var stepMarker:Marker;
	turnCounter++;

	if (turnCounter <= dir.getRoute(0).numSteps) {
		stepText = dir.getRoute(0).getStep(turnCounter-1).descriptionHtml;
		stepMarker = new Marker(dir.getRoute(0).getStep(turnCounter-1).latLng, new MarkerOptions({label: turnCounter.toString()}));
		map.addOverlay(stepMarker);
		mc_input.step.htmlText = "Step " + turnCounter + ": " + stepText;
	} else {
		mc_input.getTurnByTurnDirections.enabled = false;
		mc_input.step.htmlText = "Arrive at " + mc_input.to.text + " : " + dir.getRoute(0).summaryHtml;
	}
}

用Google Maps API可以做的东西应该还是挺多的，比如用户的地理定位，导航，地图游戏等。。。等有需要再看吧，哈。。

Some Related Posts

• 2009/05/15 -- AAS3WDP-Chapter 6 Remote Proxy 远程代理 (0)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (0)
• 2009/06/24 -- Flash-Adobe’s Flash to ship on new Android phone (0)
• 2009/06/18 -- Flash-Transparent时在FF和Safari下无法输入中文的解决方案 (0)