对象回避主题的完整意义是指，在机车行走的路线中存在一些障碍物，机车必须绕开、防止触碰到它们。听上去和碰撞检测有关，然而这仅仅是发生在预测阶段，也就是：“以我当前的速度行驶下去，可能就会撞到它了。”

“回避行为”和“避开行为”、“躲避行为”都有所区别，“避开”和“躲避”都是针对单个目标的，而且机能方面“回避行为”更为复杂。

既然是“回避行为”，那么就需要障碍物咯，这里的障碍物是Circle对象。Circle.as如下：

package {
	import flash.display.Sprite;
	public class Circle extends Sprite {
		private var _radius:Number;
		private var _color:uint;
		public function Circle (radius:Number, color:uint = 0x000000) {
			_radius = radius;
			_color = color;
			graphics.lineStyle (0, _color);
			graphics.drawCircle (0, 0, _radius);
		}
		public function get radius ():Number {
			return _radius;
		}
		public function get position ():Vector2D {
			return new Vector2D(x, y);
		}
	}
}

很简单明了的一个类，有两个只读属性，半径和位置。由于是在向量环境中计算，所以位置返回一个2D向量。
具体的算法比较复杂，其中预测碰撞的代码是基于David M.Bourg和Glenn Seemann所著的《游戏开发中的人工智能》。
下边图示：

回避的实现代码如下：

//回避行为
public function avoid (circles: Array):void {
	for (var i: int=0; i < circles.length; i++) {
		var circle:Circle=circles[i] as Circle;
		var heading:Vector2D=_velocity.clone().normalize();
		// 障碍物和机车间的位移向量
		var difference:Vector2D=circle.position.subtract(_position);
		var dotProd:Number=difference.dotProd(heading);
		// 如果障碍物在机车前方
		if (dotProd>0) {
			// 机车的“触角”
			var feeler:Vector2D=heading.multiply(_avoidDistance);
			// 位移在触角上的映射
			var projection:Vector2D=heading.multiply(dotProd);
			// 障碍物离触角的距离
			var dist:Number=projection.subtract(difference).length;
			// 如果触角（在算上缓冲后）和障碍物相交
			// 并且位移的映射的长度小于触角的长度
			// 我们就说碰撞将要发生，需改变转向
			if (dist < circle.radius + _avoidBuffer && projection.length < feeler.length) {
				// 计算出一个转90度的力
				var force:Vector2D=heading.multiply(_maxSpeed);
				force.angle+=difference.sign(_velocity)*Math.PI/2;
				// 通过离障碍物的距离，调整力度大小，使之足够小但又能避开
				force=force.multiply(1.0-projection.length/feeler.length);
				// 叠加于转向力上
				_steeringForce=_steeringForce.add(force);
				// 刹车——转弯的时候要放慢机车速度，离障碍物越接近，刹车越狠。
				_velocity=_velocity.multiply(projection.length/feeler.length);
			}
		}
	}
}

Some Random Posts

• 2008/10/29 -- PHP验证码生成和验证 (0)
• 2009/02/05 -- http://blog.to.it介绍 (0)
• 2009/01/09 -- Wordpress-日志存档输出为下拉选择框 (0)
• 2008/09/05 -- Flash在Safari下无法输入中文 (2)
• 2010/02/08 -- jQuery – Plupload 文件批量上传 (0)
• 2009/01/15 -- Flash-AS2和AS3加载XML (0)
• 2010/05/13 -- AS3-LightOut (8)
• 2009/03/26 -- PHP-Web Client Class Snoopy (1)
• 2009/06/24 -- Flash-Adobe’s Flash to ship on new Android phone (0)
• 2008/12/26 -- WordPress2.8功能需求投票中 (0)