//设置舞台属性,坐上角对齐,不拉伸
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;

//new一个Role类的实例出来,并居中显示
var mRole = new Role(stage);
addChild(mRole);
setCenter(mRole);

function setCenter(obj:DisplayObject):void{
	obj.x = (stage.stageWidth - obj.width)/2;
	obj.y = (stage.stageHeight - obj.height)/2;
}

//onResize事件
stage.addEventListener(Event.RESIZE,mResize);
function mResize(e:Event):void{
	//场景大小变化时的操作
}

然后是这个Role类：

package {
	import flash.display.Sprite;
	import flash.display.Stage;
	import flash.geom.Rectangle;
	import flash.events.*;

	public class Role extends Sprite {
		private var mStage:Stage;//根场景的stage
		private var mSpeed:int = 10;//移动速度

		public function Role(stage:Stage):void {
			mStage = stage;
			//绘制形状
			draw();
			//添加事件监听
			addEventListeners();
		}
		private function draw():void {
			with (graphics) {
				beginFill(0x999999);
				lineStyle(1, 0x000000);
				drawCircle(0, 0, 10);
				endFill();
			}
		}
		private function addEventListeners():void{
			addEventListener(MouseEvent.MOUSE_OVER,mOver);//鼠标 hover
			addEventListener(MouseEvent.MOUSE_OUT,mOut);//鼠标 out
			addEventListener(MouseEvent.MOUSE_DOWN,mDown);//鼠标 down,PS:down和click是有区别的，click包含了down和up2个事件
			mStage.addEventListener(MouseEvent.MOUSE_UP,mUp);
			mStage.addEventListener(KeyboardEvent.KEY_DOWN, mKeyDown);//Keyboard事件
		}
		private function mOver(e:MouseEvent):void{
			alpha = 0.5;
		}
		private function mOut(e:MouseEvent):void{
			alpha = 1;
		}
		private function mDown(e:MouseEvent):void{
			startDrag(true,new Rectangle(0,0,mStage.stageWidth,mStage.stageHeight));
		}
		private function mUp(e:MouseEvent):void{
			stopDrag();
		}
		private function mKeyDown(e:KeyboardEvent):void{
			if (e.keyCode==37) {
				x -= mSpeed;
			} else if (e.keyCode == 39) {
				x += mSpeed;
			} else if (e.keyCode == 38) {
				y -= mSpeed;
			} else if (e.keyCode == 40) {
				y += mSpeed;
			}
			checkWall(new Rectangle(0,0,mStage.stageWidth,mStage.stageHeight));
		}
		//四周边界碰撞修正
		private function checkWall(rect:Rectangle):void{
			if(x < =rect.left){
				x = rect.left;
			}
			if(x >= rect.right){
				x = rect.right;
			}
			if(y < =rect.top){
				y = rect.top;
			}
			if(y >= rect.bottom){
				y = rect.bottom;
			}
		}
	}
}

Some Related Posts

• 2009/04/06 -- AS3-自定义事件攻略 (2)

package {
	import Customer;
	import Waiter;
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.events.MouseEvent;

	public class Barbershop extends Sprite {
		var customDF:Customer=new Customer("DFdou");
		var waiter:Waiter=new Waiter("路人A");
		public function Barbershop () {
			addChild (waiter);
			btnCutHair.addEventListener (MouseEvent.CLICK,cutHair);
			btnSpecial.addEventListener (MouseEvent.CLICK,special);
		}
		function cutHair (_evt:MouseEvent) {
			customDF.addEventListener (ServerEvent.CUT_HAIR,waiter.serve);
			customDF.callServe (ServerEvent.CUT_HAIR,"MM1");
			customDF.removeEventListener (ServerEvent.CUT_HAIR,waiter.serve);
		}
		function special (_evt:MouseEvent) {
			customDF.addEventListener (ServerEvent.SPECIAL,waiter.serve);
			customDF.callServe (ServerEvent.SPECIAL,"MM2");
			customDF.removeEventListener (ServerEvent.SPECIAL,waiter.serve);
		}
		public function showInfo (_str:String) {
			txtInfo.appendText (_str+"\n");
		}
	}
}

自定义事件类ServerEvent.as：

package {
	import flash.events.Event;
	public class ServerEvent extends Event{
		public static const CUT_HAIR:String="cut_hair";
		public static const SPECIAL:String="special";
		public var _server:String;//指定个变量来存放服务人员
		public function ServerEvent (eventType:String):void {
			super(eventType);
		}
	}
}

Customer顾客类Customer.as：

package {
	import flash.events.EventDispatcher;
	public class Customer extends EventDispatcher {
		public var _name:String;
		public function Customer (name:String):void {
			_name=name;
		}
		public function callServe(eventType:String,server:String){
			var serverEvent:ServerEvent=new ServerEvent(eventType);
			serverEvent._server=server;//指定服务的人
			dispatchEvent(serverEvent);//发送事件
		}
	}
}

Waiter类Waiter.as：

package {
	import flash.display.Sprite;
	public class Waiter extends Sprite{
		public var _name:String;
		public function Waiter (name:String) {
			_name=name;
		}
		public function serve (_evt:ServerEvent) {
			//调用root里的函数，这里是用来做Demo用到～
			Object(root).showInfo("你需要"+_evt._server+"服务,服务类型为:"+_evt.type);
		}
	}
}

自定义事件的具体流程：
1.自定义好事件类；
2.注册事件侦听器；例子中为Custom callServe
3.发送dispatch事件；
4.侦听事件，处理；例子中为Waiter serve
5.移除侦听。

Some Related Posts

• 2009/05/18 -- AS3-无聊的密码生成器 (3)
• 2009/03/07 -- AS3-用addEventListener()方法的useCapture参数控制事件流 (6)
• 2010/03/18 -- AS3-Mapppp~的一个生成方案 (3)
• 2010/02/04 -- AS3-aSpaceEscape 迷宫脱离游戏(二)地图生成部分 (0)
• 2010/02/03 -- AS3-aSpaceEscape 迷宫脱离游戏(一)分析 (0)
• 2010/01/21 -- Flash-鼠标,键盘事件 (3)
• 2009/11/26 -- AS3-Caurina 动画类 (1)
• 2009/11/24 -- AS3-SharedObject Flash的Cookie (0)
• 2009/11/23 -- AS3-Captcha验证码类 (7)
• 2009/11/20 -- AS3-Effect explode 图片爆炸效果 (2)