Demo在这里：

下边来讲下代码部分，比较简单，3个类搞定。

LightOut.as:
[js]
package {
import flash.display.Sprite;
import flash.events.MouseEvent;

public class LightOut extends Sprite {
private var _lv = 0;
private var _map:Map;

public function LightOut() {
init();
}

private function init():void {
_map = new Map(_lv);
addChild(_map);
addEventListeners();
}
private function addEventListeners():void {
addEventListener(MouseEvent.MOUSE_DOWN, changeLight);
}
private function changeLight(e:MouseEvent):void
{
var tx:int = mouseX / Config.TILE_SIZE < < 0;
var ty:int = mouseY / Config.TILE_SIZE << 0;
var numRows:int = _map.getMapData().length;
var numCols:int = _map.getMapData()[0].length;

for (var i:int = 0; i < numRows; i++) {
for (var j:int = 0; j < numCols; j++) {
if (Math.abs(i - tx) + Math.abs(j - ty) <= 1) {
if (_map.getMapData()[j][i] == 0) {
_map.setMapData(j,i,1);
}else {
_map.setMapData(j,i,0);
}
}
}
}
}
}
}
[/js]
Config.as，用来配置常数和地图。
[js]
package
{
/**
* ...
* @author DFdou
*/
public class Config
{
public static const TILE_SIZE = 25;

public static const LIGHT_ON = 1;
public static const LIGHT_OFF = 0;

public static const MAP:Array = [
[
[0, 1, 0, 1, 0],
[0, 1, 0, 1, 0],
[1, 1, 1, 1, 1],
[0, 1, 0, 1, 0],
[0, 1, 0, 1, 0]
],
];
}
}
[/js]
Map.as，直接从Sokoban那拷过来的，基本上差不多@.@
[js]
package
{
import flash.display.Sprite;
import flash.events.Event;

/**
* ...
* @author DFdou
*/
public class Map extends Sprite
{
private var _lv:uint;//关卡
private var _mapData:Array = [];//map数据

public function Map(lv:uint=0)
{
_lv = lv;
initMapData(lv);
}
private function initMapData(lv:uint = 0) {
for (var i = 0; i < Config.MAP[lv].length; i++) {
_mapData[i] = [];
for (var j = 0; j < Config.MAP[lv][i].length; j++) {
_mapData[i][j] = Config.MAP[lv][i][j];
}
}
drawMap();
}
private function drawMap() {
var tile:Tile;
for (var i = 0; i < _mapData.length; i++) {
for (var j = 0; j < _mapData[i].length; j++) {
tile = new Tile();
tile.x = j * Config.TILE_SIZE;
tile.y = i * Config.TILE_SIZE;
tile.gotoAndStop(_mapData[i][j]+1);
addChild(tile);
}
}
}
private function repaintMap() {
clearMap();
drawMap();
}
private function clearMap() {
while (numChildren > 0) {
removeChildAt(0);
}
}
private function checkSuccess() {
if(isSuccess()){
trace("Success");
//nextLevel();
}
}
private function isSuccess():Boolean {
var success:Boolean = true;
var numRow:int = _mapData.length;
var numCols:int = _mapData[0].length;
for (var i = 0; i < numRow; i++) {
for (var j = 0; j < numCols; j++) {
success = success && (_mapData[i][j] == Config.LIGHT_ON);
}
}
return success;
}
public function setMapData(py:int, px:int, type:int) {
_mapData[py][px] = type;
repaintMap();
checkSuccess();
}
public function getMapData():Array {
return _mapData;
}
}
}
[/js]
感觉也没什么好讲的地方，就这样吧，有问题请留言，别客气～

Some Related Posts

• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/04/23 -- GAME-Quake Live (0)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/03/08 -- GAME-What’s in your brain? 你的脑内是什么? (7)
• 2009/02/24 -- AS3-MC的移动控制 (3)

方向键控制移动，红色的方块是你～
UI嘛，就不说了，网上偷了点图，就这么放着了，有兴趣的可以弄弄呗。

Source code:https://dl.dropbox.com/u/477487/flash/game/sokoban.rar

PS：如果该地址被和谐，而你又想要源代码，联系我，服务很周到的～

推箱子的实现方法很多，各有各的做法，下边是我的实现方式：
Sokoban.as:
[js]
package {
import flash.display.Sprite;
import flash.events.Event;
/**
* ...
* @author DFdou
*/
public class Sokoban extends Sprite {
private var _lv = 0;
private var _map:Map;

public function Sokoban() {
init();
}
private function init() {
_map = new Map(_lv);
addChild(_map);

var role:Role = new Role(stage,_map,_lv);
addChild(role);
}

}
}
[/js]
文档类要干的事儿就是生成一个map，一个role。

Map.as:
[js]
package
{
import flash.display.Sprite;
import flash.events.Event;

/**
* ...
* @author DFdou
*/
public class Map extends Sprite
{
private var _lv:uint;//关卡
private var _mapData:Array = [];//map数据

public function Map(lv:uint=0)
{
_lv = lv;
initMapData(lv);
}
private function initMapData(lv:uint = 0) {
for (var i = 0; i < MapData.MAP[lv].length; i++) {
_mapData[i] = [];
for (var j = 0; j < MapData.MAP[lv][i].length; j++) {
_mapData[i][j] = MapData.MAP[lv][i][j];
}
}
drawMap();
}
private function drawMap() {
var tile:Tile;
for (var i = 0; i < _mapData.length; i++) {
for (var j = 0; j < _mapData[i].length; j++) {
if(_mapData[i][j]!=0){
tile = new Tile();
tile.x = j * Config.TILE_SIZE;
tile.y = i * Config.TILE_SIZE;
tile.gotoAndStop(_mapData[i][j]);
addChild(tile);
}
}
}
}
private function repaintMap() {
clearMap();
drawMap();
}
private function clearMap() {
while (numChildren > 0) {
removeChildAt(0);
}
}
private function checkSuccess() {
if(isSuccess()){
trace("Success");
//nextLevel();
}
}
private function isSuccess():Boolean {
var success:Boolean = true;
for (var i = 0; i < MapData.MAP[_lv].length; i++) {
for (var j = 0; j < MapData.MAP[_lv][i].length; j++) {
//4是目标点
if (MapData.MAP[_lv][i][j] == MapData.TARGET || MapData.MAP[_lv][i][j] == MapData.SPECIAL) {
if ((_mapData[i][j] == MapData.BOX || _mapData[i][j] == MapData.SPECIAL)) {
trace(i,j,_mapData[i][j]);
}
success = success && (_mapData[i][j]==MapData.BOX || _mapData[i][j]==MapData.SPECIAL);
}
}
}
return success;
}
public function setMapData(py:int, px:int, type:int) {
_mapData[py][px] = type;
//trace(py,px,_mapData[py][px]);
repaintMap();
checkSuccess();
}
public function getMapData():Array {
return _mapData;
}
}
}
[/js]
那Map要干嘛呢，自然就是绘制Map咯，先从MapData取得对应关卡的数据，然后绘制Map，顺便在这里边判断是否过关～

接下去就是Role.as:
[js]
package
{
import flash.display.Sprite;
import flash.display.Stage;
import flash.events.KeyboardEvent;

/**
* ...
* @author DFdou
*/
public class Role extends Sprite
{
private var _lv:uint;
private var _map:Map;

public function Role(stage:Stage,map:Map,lv:uint=0)
{
_lv = lv;
_map = map;
getPosition();

stage.addEventListener(KeyboardEvent.KEY_DOWN, moveRole);
}

private function getPosition() {
for (var i = 0; i < MapData.MAP[_lv].length; i++) {
for (var j = 0; j < MapData.MAP[_lv][i].length; j++) {
//6是role位置
if(MapData.MAP[_lv][i][j]==MapData.ROLE){
x = j * Config.TILE_SIZE;
y = i * Config.TILE_SIZE;
}
}
}

}
private function moveRole(e:KeyboardEvent) {
switch(e.keyCode) {
case 37://left
move( -1, 0);
break;
case 38://top
move(0, -1);
break;
case 39://right
move(1, 0);
break;
case 40://down
move(0, 1);
break;
default:
trace(e.keyCode);
break;
}
}
private function move(px:int, py:int) {
if (canMove(px,py)) {
x += px * Config.TILE_SIZE;
y += py * Config.TILE_SIZE;
}
}
//1是墙壁,2是路,3是箱子,4是目的地
private function canMove(px:int, py:int):Boolean {
var nextPx:int = x / Config.TILE_SIZE + px;
var nextPy:int = y / Config.TILE_SIZE + py;
//移动范围超出和碰壁的情况
if (isRoad(nextPy, nextPx)) {
return true;
}
//前边是箱子
else if (_map.getMapData()[nextPy][nextPx] == MapData.BOX || _map.getMapData()[nextPy][nextPx] == MapData.SPECIAL) {
if (canBoxMove(nextPy, nextPx, py, px)) {
moveBox(nextPy,nextPx,py,px);
return true;
}
}
return false;
}
private function canBoxMove(basePy:int, basePx:int, py:int, px:int):Boolean {
var nextPx:int = basePx+px;
var nextPy:int = basePy+py;
if (isRoad(nextPy, nextPx)) {
return true;
}
return false;
}
private function isRoad(nextPy:int, nextPx:int):Boolean {
if (nextPy >= 0 && nextPx >= 0 && nextPy < = _map.getMapData().length && nextPx <= _map.getMapData()[0].length && (_map.getMapData()[nextPy][nextPx] == MapData.ROAD || _map.getMapData()[nextPy][nextPx] == MapData.TARGET || _map.getMapData()[nextPy][nextPx] == MapData.ROLE)) {
return true;
}
return false;
}
private function moveBox(basePy:int, basePx:int, py:int, px:int) {
//如果当前格子不是目标点
switch(MapData.MAP[_lv][basePy][basePx]) {
//目标点
case MapData.SPECIAL:
case MapData.TARGET:
_map.setMapData(basePy, basePx, MapData.TARGET);
break;
default:
_map.setMapData(basePy, basePx, MapData.ROAD);
break;
}
_map.setMapData(basePy+py,basePx+px,MapData.BOX);
}
}
}
[/js]
Role类比较明了，就是Role的移动控制，主要处理部分就是移动的控制，先预算下要移动到的位置是否允许移动，是的话就移动被。
如果前边是箱子，就判断箱子能不能移动，能移动就移动，不能移动就拉倒～

地图数据MapData.as:
[js]
package
{
/**
* ...
* @author DFdou
*/
public class MapData
{
public static const WALL:uint = 1;//墙壁
public static const ROAD:uint = 2;//路
public static const BOX:uint = 3;//箱子
public static const TARGET:uint = 4;//目的地
public static const SPECIAL:uint = 5;//箱子直接在目的地
public static const ROLE:uint = 6;//角色

public static const MAP:Array = [
[
[0, 0, 1, 1, 1, 1, 1, 1, 0, 0],
[0, 0, 1, 2, 2, 2, 2, 1, 0, 0],
[1, 1, 1, 2, 2, 2, 2, 1, 1, 1],
[1, 2, 2, 2, 6, 5, 2, 2, 2, 1],
[1, 1, 1, 3, 2, 1, 1, 1, 1, 1],
[0, 0, 1, 4, 2, 1, 0, 0, 0, 0],
[0, 0, 1, 1, 1, 1, 0, 0, 0, 0]],
];

}

}
[/js]
关卡和组件对应描述文件。

全局配置文件Config.as：
[js]
package
{
/**
* ...
* @author DFdou
*/
public class Config
{
public static const TILE_SIZE = 30;
}
}
[/js]
这里是全局的配置。更新了下代码，修正了下边这2个问题。
恩，当时写的时候做的不好把Role的位置单独弄出来了，应该放到MapData里的…现在这样太不OOP了……另外，在配置地图的时候发现另一个问题，如果一开始箱子就在目标点的情况没被考虑在内……

Some Related Posts

• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/20 -- AS3-Sokoban推箱子-寻路扩展 (2)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/04/23 -- GAME-Quake Live (0)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/03/08 -- GAME-What’s in your brain? 你的脑内是什么? (7)

源代码下载地址:http://dl.dropbox.com/u/477487/flash/game/mapMove.rar
只做了移动，重叠和阻挡的部分没做，短时间内不会有时间做的=,=
主要逻辑是这样，选中Role就显示可以行走的范围，选其中一点之后Role就移动。
下边看下简单的实现。主要是OverlayView.as和Role.as，我很懒，其他代码大家自己看……

OverlayView.as用来显示Path。
[js]
package org.nwhy.game{
import flash.display.Sprite;
import flash.events.MouseEvent;

public class OverlayView extends Sprite {
private var target;//目标
public var isActived:Boolean;
public function OverlayView(target:Sprite) {
this.target = target;
showPath();
}
private function showPath() {
removeAllChildren();
var targetPosition:uint = target.movement;
for (var i:uint=0; i for (var j:uint=0; j var offset:uint = Math.abs(i-targetPosition)+Math.abs(j-targetPosition);
//trace("x:"+Math.abs(i-targetPosition)+"y:"+Math.abs(j-targetPosition));
if (offset<=target.movement) {
var path:Path = new Path();
path.alpha = 0.5;
path.x = i*Tile.SIZE;
path.y = j*Tile.SIZE;
path.addEventListener(FEvent.PATH_SELECTED,pathSelected);
addChild(path);
}
}
}
}
private function pathSelected(e:FEvent){
var evt:FEvent = new FEvent(FEvent.PATH_SELECTED);
var disX = e.currentTarget.x/Tile.SIZE - target.movement;
var disY = e.currentTarget.y/Tile.SIZE - target.movement;
evt.info = {disX:disX,disY:disY};
dispatchEvent(evt);
}
private function removeAllChildren() {
while (numChildren>0) {
removeChildAt(0);
}
}
}
}
[/js]
Role.as:
[js]
package org.nwhy.game{
import flash.display.MovieClip;
import flash.events.MouseEvent;

public class Role extends MovieClip{
public var movement;//行走步数
public function Role(colNumer:uint,rowNumber:uint,mProperty:Property){
this.x = colNumer * Tile.SIZE;//x位置
this.y = rowNumber * Tile.SIZE;//y位置
movement = mProperty.movement;
gotoAndStop(mProperty.faceType);
addEventListeners();
}
private function addEventListeners(){
addEventListener(MouseEvent.MOUSE_DOWN,mDown);
}
private function mDown(e:MouseEvent){
if(Controller.overlay){//先判断有无实例
if(Controller.overlay.parent){//再判断有无被加入到场景
parent.removeChild(Controller.overlay);
}
}
Controller.overlay = new OverlayView(this);
Controller.overlay.x = this.x - movement*Tile.SIZE;
Controller.overlay.y = this.y - movement*Tile.SIZE;

parent.addChild(Controller.overlay);
Controller.overlay.addEventListener(FEvent.PATH_SELECTED,positionToGo);
}
private function positionToGo(e:FEvent){
//trace(this.x+":"+this.y+"---"+e.info.disX+":"+e.info.disY);
this.x += e.info.disX * Tile.SIZE;
this.y += e.info.disY * Tile.SIZE;
removeOverlay();
}
private function removeOverlay(){
parent.removeChild(Controller.overlay);
}
}
}
[/js]

Some Related Posts

• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/04/23 -- GAME-Quake Live (0)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/03/08 -- GAME-What’s in your brain? 你的脑内是什么? (7)
• 2009/02/24 -- AS3-MC的移动控制 (3)

var PICWIDTHNUM:uint = 13;
var PICHEIGHTNUM:uint = 10;
var PICSIZE:uint = 40;
var aryPic:Array = [1,2,3,4,5,6,7,8];
var aryPicType:Array = [];
var aryPath:Array = [];
var aryCrossPath:Array = [];

var WIDTHNUM:uint = PICWIDTHNUM + 2;
var HEIGHTNUM:uint = PICHEIGHTNUM + 2;
var PATHSIZE:uint = 40;

var clkFlag:Boolean = false;
var firstObj:Pic;
var secondObj:Pic;

//生成路径图
setPath ();
function setPath () {
for (var i:uint=0; i < WIDTHNUM; i++) {
aryPath[i] = [];
for (var j:uint=0; j < HEIGHTNUM; j++) {
var path = new Path();
path.x = PATHSIZE * i;
path.y = PATHSIZE * j;

path.disX = i;
path.disY = j;
path.name = "path" + path.disX * 8 + path.disY;
path.txt_disInfo.text = "(" + path.disX + "," + path.disY + ")";

if (i ==0 || i == (WIDTHNUM - 1) || j == 0 || j ==(HEIGHTNUM - 1)) {
setCrossFlag (i,j,path,true);
} else {
setCrossFlag (i,j,path,false);
}
//trace(path.disX);
//trace(path.disY);
addChild (path);
}
}
//trace (aryPath);
}
//设置路径的可通过和不可通过crossFlag
function setCrossFlag (i:uint,j:uint,path:Path,flag:Boolean) {
aryPath[i][j] = flag;
path.crossFlag = flag;
path.txt_CrossFlag.text = String(flag);
}

//生成图片数组并随机打乱
setTypeArray ();
function setTypeArray () {
var i:uint = 0;
while (i < PICWIDTHNUM * PICHEIGHTNUM / 2) {
//picArray是图片数组
aryPicType.push (i % (aryPic.length) +1);
aryPicType.push (i % (aryPic.length) +1);
++i;
}
aryPicType = aryRandom(aryPicType);
}
//数组随机排列函数
function aryRandom (ary:Array):Array {
var ary_temp:Array = new Array();
for (var i:int = ary.length; i > 0; i--) {
var int_num:Number = int(Math.random() * ary.length);
ary_temp.push (ary[int_num]);
ary.splice (int_num, 1);
}
return ary_temp;
}
//图片设置部分
initPic ();
var startNum:uint = 0;
function initPic () {
for (var i:uint=0; i < PICWIDTHNUM; i++) {
for (var j:uint=0; j < PICHEIGHTNUM; j++) {
setPic (i, j, aryPicType[startNum]);
startNum++;
}
}
}
//设置图片类型，位置，以及点击事件
function setPic (i:uint, j:uint, type:uint) {
var pic = new Pic();
pic.x = PATHSIZE + PICSIZE * i;
pic.y = PATHSIZE + PICSIZE * j;

pic.disX = i + 1;
pic.disY = j + 1;
pic.pType = type;
pic.name = "pic" + pic.disX * 8 + pic.disY;
//trace(pic.name);
pic.txt_disInfo.text = "(" + pic.disX + "," + pic.disY + ")";
pic.gotoAndStop (type);
addChild (pic);
pic.addEventListener (MouseEvent.CLICK,picCLK);
}
//点击事件具体处理部分
function picCLK (_evt:MouseEvent) {
//trace(_evt.currentTarget.name);
if (! clkFlag) {
firstObj = _evt.currentTarget as Pic;
clkFlag = true;
} else if (firstObj == (_evt.currentTarget as Pic)) {
//trace ("the same one");
/*firstObj = _evt.currentTarget as Pic;
clkFlag = true;*/
clkFlag = true;
} else {
secondObj = _evt.currentTarget as Pic;
if (checkTwoObj()) {
matchSucc ();
} else {
matchFailed ();
}
aryCrossPath = [];
}

/*trace ("-------------------------------------------");
trace ("firstObj"+firstObj.pType);
trace ("secondObj"+secondObj.pType);
trace ("firstObj.disX"+firstObj.disX);
trace ("firstObj.disY"+firstObj.disY);
trace ("secondObj.disX"+secondObj.disX);
trace ("secondObj.disY"+secondObj.disY);
trace ("-------------------------------------------");*/
}
//判断firstObj和secondObj是否可以消除
function checkTwoObj ():Boolean {
if (matchTwoObj()) {
//trace ("same type");
if (testCrossAbleXY(firstObj,secondObj)) {
return true;
}
}
return false;
}

function matchFailed () {
firstObj = secondObj;
secondObj = null;
clkFlag = true;
//trace(aryCrossPath);
}

function matchSucc () {
var firstPathName = "path" + firstObj.name.substr(3);
var firstPath:Path = getChildByName(firstPathName) as Path;
var secondPathName = "path" + secondObj.name.substr(3);
var secondPath:Path = getChildByName(secondPathName) as Path;
setCrossFlag (firstObj.disX,firstObj.disY,firstPath,true);
setCrossFlag (secondObj.disX,secondObj.disY,secondPath,true);
removeChild (firstObj);
removeChild (secondObj);
firstObj = null;
secondObj = null;
clkFlag = false;
drawLine(aryCrossPath);
//trace(aryCrossPath);
}
//连线函数
function drawLine(_ary:Array){
//trace("drawLine");
var lineSP:Shape = new Shape();
lineSP.graphics.beginFill(0x000000);
lineSP.graphics.lineStyle(1, 0x000000);
//lineSP.graphics.moveTo(_ary[0][0]*PICSIZE+0.5*PICSIZE,_ary[0][1]*PICSIZE+0.5*PICSIZE);
for(var i:uint = 0; i<(_ary.length-1); i++){
lineSP.graphics.moveTo(_ary[i][0]*PICSIZE+0.5*PICSIZE,_ary[i][1]*PICSIZE+0.5*PICSIZE);
lineSP.graphics.lineTo(_ary[(i+1)][0]*PICSIZE+0.5*PICSIZE,_ary[(i+1)][1]*PICSIZE+0.5*PICSIZE);
//trace(_ary[i][0],_ary[i][1]);
}
lineSP.graphics.endFill();
addChild(lineSP);
setTimeout(clearLine,1000,lineSP);
}
//移除连线
function clearLine(_lineSP:Shape){
_lineSP.graphics.clear();
}
//判断firstObj和secondObj是否是同一个类型的图，是返回true，不是返回false
function matchTwoObj ():Boolean {
if (firstObj.pType == secondObj.pType) {
return true;
} else {
return false;
}
}
//同一列方向(X相同时)的直接连通检测
function testCrossAbleX (disX:uint, firstObjDisY:uint, secondObjDisY:uint):Boolean {
var maxY = Math.max(firstObjDisY,secondObjDisY);
var minY = Math.min(firstObjDisY,secondObjDisY);
if ((maxY - minY)>1) {
for (var i:uint = minY+1; i< maxY; i++) {
if (! aryPath[disX][i]) {
//trace ("testCrossAbleX failed");
return false;
}
}
}
//trace ("testCrossAbleX succ");
return true;
}
//同一行方向(Y相同时)的直接连通检测
function testCrossAbleY (disY:uint, firstObjDisX:uint, secondObjDisX:uint):Boolean {
var maxX = Math.max(firstObjDisX,secondObjDisX);
var minX = Math.min(firstObjDisX,secondObjDisX);
if ((maxX - minX)>1) {
for (var i:uint = minX+1; i< maxX; i++) {
if (! aryPath[i][disY]) {
//trace ("testCrossAbleY failed");
return false;
}
}
}
//trace ("testCrossAbleY succ");
return true;
}
//firstObj和secondObj不同列也不同行时的检测
function testCrossAbleXY (firstObj:Pic, secondObj:Pic):Boolean {
var aryFlag1:Boolean = false;
var aryFlag2:Boolean = false;
if ((firstObj.disX == secondObj.disX && testCrossAbleX(firstObj.disX,firstObj.disY,secondObj.disY)) || (firstObj.disY == secondObj.disY && testCrossAbleY(firstObj.disY,firstObj.disX,secondObj.disX))) {
var aryP1:Array = [firstObj.disX,firstObj.disY];
var aryP2:Array = [secondObj.disX,secondObj.disY];
aryCrossPath.push(aryP1);
aryCrossPath.push(aryP2);
return true;
} else {
for (var i:uint = 0; i var flagH1:Boolean;
var flagH2:Boolean;
var flagH3:Boolean;
if (aryPath[firstObj.disX][i]) {
flagH1 = testCrossAbleX(firstObj.disX,i,firstObj.disY);
if (i == secondObj.disY) {
flagH2 = testCrossAbleY(i,firstObj.disX,secondObj.disX);
} else {
flagH2 = aryPath[secondObj.disX][i] && testCrossAbleY(i,firstObj.disX,secondObj.disX);
}
flagH3 = testCrossAbleX(secondObj.disX,i,secondObj.disY);
//aryFlag1[i] = (testCrossAbleX(firstObj.disX,i,firstObj.disY) && aryPath[firstObj.disX][i]) && (testCrossAbleY(i,firstObj.disX,secondObj.disX) && aryPath[secondObj.disY][i]) && testCrossAbleX(secondObj.disX,i,secondObj.disY);
aryFlag1 = aryFlag1 || (flagH1 && flagH2 && flagH3);
if (aryFlag1) {
var aryPx1:Array = [firstObj.disX,firstObj.disY];
var aryPx2:Array = [firstObj.disX,i];
var aryPx3:Array = [secondObj.disX,i];
var aryPx4:Array = [secondObj.disX,secondObj.disY];
aryCrossPath.push(aryPx1);
aryCrossPath.push(aryPx2);
aryCrossPath.push(aryPx3);
aryCrossPath.push(aryPx4);
return true;
}
}
}
for (var j:uint = 0; j var flagW1:Boolean;
var flagW2:Boolean;
var flagW3:Boolean;
if (aryPath[j][firstObj.disY]) {
flagW1 = testCrossAbleY(firstObj.disY,j,firstObj.disX);
if (j == secondObj.disX) {
flagW2 = testCrossAbleX(j,firstObj.disY,secondObj.disY);
} else {
flagW2 = aryPath[j][secondObj.disY] && testCrossAbleX(j,firstObj.disY,secondObj.disY);
}
flagW3 = testCrossAbleY(secondObj.disY,j,secondObj.disX);
aryFlag2 = aryFlag2 || (flagW1 && flagW2 && flagW3);
if (aryFlag2) {
var aryPy1:Array = [firstObj.disX,firstObj.disY];
var aryPy2:Array = [j,firstObj.disY];
var aryPy3:Array = [j,secondObj.disY];
var aryPy4:Array = [secondObj.disX,secondObj.disY];
aryCrossPath.push(aryPy1);
aryCrossPath.push(aryPy2);
aryCrossPath.push(aryPy3);
aryCrossPath.push(aryPy4);
return true;
}
}
}
}
aryCrossPath= [];
return false;
}
[/js]
Pic类就是图片了,这里图方便我在库里丢了个元件弄了8桢,每桢画了不一样的颜色.
该类有3个属性,所在列数disX,所在行数disY,图片类型pType.
[js]
package{
import flash.display.MovieClip;
public class Pic extends MovieClip{
public var disX;
public var disY;
public var pType;
public function Pic(){}
}
}
[/js]

Some Related Posts

• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2010/03/18 -- AS3-Mapppp~的一个生成方案 (3)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2010/02/04 -- AS3-aSpaceEscape 迷宫脱离游戏(二)地图生成部分 (0)

public class Game extends Sprite{
private var _role:Role;
private var _enemy:Sprite;
private var _time:TimeCount;
private var _enemyTotal:uint;
private var _gameFlag:Boolean;

private var startBtn:Button;
private var gameInfo:TextField;

//存储四个方向键是否按下的变量
private var leftArrow:Boolean=false;
private var rightArrow:Boolean=false;
private var upArrow:Boolean=false;
private var downArrow:Boolean=false;

public function Game():void{
startBtn = new Button();
startBtn.label = "StartGame";
startBtn.x=(Config.STAGE_W-startBtn.width)/2;
startBtn.y=(Config.STAGE_H-startBtn.height)/2;
addChild(startBtn);
startBtn.addEventListener(MouseEvent.MOUSE_DOWN,gameStart);
gameInfo = new TextField();
gameInfo.autoSize = TextFieldAutoSize.LEFT;
gameInfo.selectable = false;
gameInfo.text = "上下左右方向键控制方块移动，被黑球击中就挂了。";
gameInfo.x = (Config.STAGE_W-gameInfo.width)/2;
gameInfo.y = startBtn.y-30;
addChild(gameInfo);
}
private function gameStart(_evt:MouseEvent):void{
startBtn.removeEventListener(MouseEvent.MOUSE_DOWN,gameStart);
startBtn.visible = false;
gameInfo.visible = false;
init();
}
private function init():void{
initTime();
initRole();
initEnemy();
}
private function initTime():void{
_time = new TimeCount();
addChild(_time);
}
private function initRole():void{
_role = new Role();
addChild(_role);
_role.x=(Config.STAGE_W-_role.width)/2;
_role.y=(Config.STAGE_H-_role.height)/2;
stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressedDown);
stage.addEventListener(KeyboardEvent.KEY_UP, keyPressedUp);
_role.addEventListener(Event.ENTER_FRAME, roleMove);
stage.addEventListener(Event.DEACTIVATE, missingStage);//Flash处于非活动状态时调用
}

private function initEnemy():void{
_enemyTotal = Config.ENEMY_TOTAL;
var t:Timer=new Timer(2000,1);
t.addEventListener(TimerEvent.TIMER, timeToCreateEnemy);
t.start();
}

private function createEnemy():void{
var enemy=new Enemy();
enemy.setRole(_role);
_enemy.addChild(enemy);
}
private function getEnemyNum():uint{
return this.numChildren;
}

private function timeToCreateEnemy(_evt:TimerEvent):void{
_enemy = new Sprite();
addChild(_enemy);
for (var i:uint=0; i<_enemytotal ; i++) {
createEnemy();
}
addEventListener(Event.ENTER_FRAME,checkFlag);
}

//按键时的检测，左上右下分别是37，38，39，40
private function keyPressedDown(_evt:KeyboardEvent) {
if (_evt.keyCode==37) {
leftArrow=true;
} else if (_evt.keyCode == 39) {
rightArrow=true;
} else if (_evt.keyCode == 38) {
upArrow=true;
} else if (_evt.keyCode == 40) {
downArrow=true;
}
}

//松开按键时
private function keyPressedUp(_evt:KeyboardEvent) {
if (_evt.keyCode==37) {
leftArrow=false;
} else if (_evt.keyCode == 39) {
rightArrow=false;
} else if (_evt.keyCode == 38) {
upArrow=false;
} else if (_evt.keyCode == 40) {
downArrow=false;
}
}
private function roleMove(_evt:Event) {
//移动的速度
var speed:Number=Config.ROLE_SPEED;
if (leftArrow) {
//MC的位置检测，下边相同
if (0<=_role.x) {
_role.x-=speed;
}
}
if (rightArrow) {
if (_role.x<=Config.STAGE_W-_role.width) {
_role.x+=speed;
}
}
if (upArrow) {
if (0<=_role.y) {
_role.y-=speed;
}
}
if (downArrow) {
if (_role.y<=Config.STAGE_H-_role.height*2) {
_role.y+=speed;
}
}
}

//Flash处于非激活状态时
private function missingStage(_evt:Event) {
leftArrow=false;
rightArrow=false;
upArrow=false;
downArrow=false;
}
private function checkFlag(_evt:Event):void{
//trace(_gameFlag);
if(_gameFlag){
_gameFlag = false;
gameOver();
}
}
private function gameOver(){

removeEventListener(Event.ENTER_FRAME,checkFlag);
_time.stopTime();

gameInfo.text = "You Failed At " + _time.getTime() + " Second!";
var format:TextFormat = new TextFormat();
format.font = "Arial";
format.color = 0xFF0000;
format.size = 30;
gameInfo.setTextFormat(format);
gameInfo.x=(Config.STAGE_W-gameInfo.textWidth)/2;
gameInfo.y=(Config.STAGE_H-gameInfo.textHeight)/2;
gameInfo.visible = true;

startBtn.visible = true;
startBtn.y = gameInfo.y + 40;
startBtn.addEventListener(MouseEvent.MOUSE_DOWN,gameStart);

//_role.roleClear();
_role.removeEventListener(Event.ENTER_FRAME, roleMove);
removeChild(_role);

while(_enemy.numChildren>0){
Enemy(_enemy.getChildAt(0)).enemyClear();
_enemy.removeChildAt(0);
}
removeChild(_enemy);
}
public function setGameFlag(_value:Boolean):void{
_gameFlag = _value;
}
}
}
[/js]

然后是一个不是很重要的类，记时类：
[js]
package{
import flash.text.TextField;
import flash.text.TextFormat;
import flash.text.TextFieldAutoSize;
import flash.utils.Timer;
import flash.events.TimerEvent;

public class TimeCount extends TextField{
private var _timeCount:uint;
private var t:Timer;
var format:TextFormat;

public function TimeCount():void{
init();
}
private function init(){
format = new TextFormat();
format.font = "Arial";
format.color = 0x666666;
format.size = 15;
format.bold = true;
_timeCount=0;
autoSize = TextFieldAutoSize.LEFT;
selectable = false;
t = new Timer(1000);
t.addEventListener(TimerEvent.TIMER,showTimeCount);
t.start();
}
private function showTimeCount(_evt:TimerEvent):void{
_timeCount++;
showTime(_timeCount);
}
private function showTime(timeCount:uint):void{
var _count = String(timeCount);
text = "Time: " + _count + " Second";
setTextFormat(format);
}
public function stopTime():void{
t.start();
t.removeEventListener(TimerEvent.TIMER,showTimeCount);
text = "";
}
public function getTime():uint{
return _timeCount;
}
}
}
[/js]
当然了，你可以加入声音类，Enemy子类，Role子类，以及其他的OOXX的OOX之类的。
或者加入开始动画，结束动画，甚至是和《特训!99》一样加入一个巧妙度的计算类？

Some Related Posts

• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (4)

import ascb.util.NumberUtilities;//来自于as3 cook book 的第三方类
import Config;//配置文件 里边存放了游戏的基本参数
import Role;//游戏角色，也就是方块

public class Enemy extends Sprite{

private var _size:uint;//大小
private var _color:uint;//颜色
private var _spdX:Number;//x轴的速度
private var _spdY:Number;//y轴的速度
private var _directionX:int;//x轴移动方向
private var _directionY:int;//y轴移动方向
private var _minSpeed:int;//最小运动速度
private var _maxSpeed:int;//最大运动速度
private var _role:Role;

public function Enemy():void {
init();
drawCircle();
_directionX = randDirection();
_directionY = randDirection();
addEventListener(Event.ENTER_FRAME,run);
}
private function init():void{
//trace(Config.STAGE_W);
//trace(Config.STAGE_H);
_minSpeed = Config.ENEMY_MINSPEED;
_maxSpeed = Config.ENEMY_MAXSPEED;
_spdX = NumberUtilities.random(_minSpeed,_maxSpeed);
_spdY = NumberUtilities.random(_minSpeed,_maxSpeed);
_size = Config.ENEMY_SIZE;
_color = Config.ENEMY_COLOR;
x = randDis()[0];
y = randDis()[1];
}
//开始位置定了4个点
private function randDis():Array{
var aryTmp:Array = [[50,50],[Config.STAGE_W-50,50],[50,Config.STAGE_H-50],[Config.STAGE_W-50,Config.STAGE_H-50]];
var rand = NumberUtilities.random(0,3);
trace(aryTmp[rand]);
return (aryTmp[rand]);
}
//x，y轴的移动方向随机值
private function randDirection():int{
var rand = NumberUtilities.random(0,1);
if(rand){
return 1;
}else{
return -1;
}
//trace(_direction);
}
//绘制圆
private function drawCircle():void{
//trace("drawCircle");
var childCircle:Shape = new Shape();
var halfSize:uint = Math.round(_size / 2);
childCircle.graphics.beginFill(_color);
childCircle.graphics.lineStyle(0,_color);
childCircle.graphics.drawCircle(halfSize, halfSize, halfSize);
childCircle.graphics.endFill();
addChild(childCircle);
}
//enemy的位移控制
public function run(_evt:Event):void {
//trace("run");
x += _spdX * (_directionX);
y += _spdY * (_directionY);
//trace(_spdX * _direction);
//out of stage的时候改变移动方向
if(x< =0 || x>=Config.STAGE_W || y< =0 || y>=Config.STAGE_H){
_spdX = NumberUtilities.random(_minSpeed,_maxSpeed);
_spdY = NumberUtilities.random(_minSpeed,_maxSpeed);
_directionX = randDirection();
_directionY = randDirection();
//本来是打算冲出屏幕就删除的
/*if (parent){
//trace("out of stage");
removeEventListener(Event.ENTER_FRAME,run);
parent.removeChild(this);
}*/
}
hitRole();
}
//判断是否和Role碰撞了
private function hitRole(){
if(hitTestObject(_role)){
Game(root).setGameFlag(true);
}
}
//设置Role
public function setRole(roleObj:Role):void{
_role = roleObj;
}
//game over时的清除操作
public function enemyClear(){
removeEventListener(Event.ENTER_FRAME,run);
}
}
}
[/js]
然后是Role类，也就是游戏主体方块，这个类很简单，绘制一个Role就可以了：
[js]
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.Graphics;
import Config;

public class Role extends Sprite {
private var _size:uint;
private var _color:uint;

public function Role():void {
init();
}
private function init():void {
_size=Config.ROLE_SIZE;
_color=Config.ROLE_COLOR;
drawRole();
}
private function drawRole():void {
var role:Shape = new Shape();
role.graphics.beginFill(_color);
role.graphics.lineStyle(0, _color);
role.graphics.drawRect(0, 0, _size, _size);
role.graphics.endFill();
addChild(role);
}
public function roleClear(){
if (parent){
parent.removeChild(this);
}
//other code
}
}
}
[/js]
最后是控制部分，请见这里《AS3-子弹躲避游戏(下)》

Some Related Posts

• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (4)

Some Related Posts

• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/03/08 -- GAME-What’s in your brain? 你的脑内是什么? (7)
• 2009/02/24 -- AS3-MC的移动控制 (3)

btnStart.buttonMode=true;
btnStart.addEventListener (MouseEvent.CLICK,gameStart);
//开始游戏
function gameStart (_evt:MouseEvent) {
var p1Name:String=trimStr(inputP1.text);
var p2Name:String=trimStr(inputP2.text);
if (checkPName (p1Name) && checkPName (p2Name)) {
txtInfoShow.text="";
btnStart.buttonMode=false;
btnStart.removeEventListener (MouseEvent.CLICK,gameStart);
var p1=new Player(p1Name);
initPlayer(p1,mcP1);
var p2=new Player(p2Name);
initPlayer(p2,mcP2);
if(p1.getDex()>=p2.getDex()){
txtInfoShow.appendText("比对敏捷值 "+p1.getName()+" 获得优先攻击权 \n");
setTimeout(doPK,2000,p1,p2);
}else{
txtInfoShow.appendText("比对敏捷值 "+p2.getName()+" 获得优先攻击权 \n");
setTimeout(doPK,2000,p2,p1);
}
} else {
txtInfoShow.appendText("请输入名字！\n");
}
}
//初始化角色
function initPlayer(_player:Player,_mc:MovieClip){
_player.setBindMC(_mc);
setTxt(_mc.txtName,String(_player.getName()));
setTxt(_mc.txtHp,String(_player.getHp()));
setTxt(_mc.txtStr,String(_player.getStr()));
setTxt(_mc.txtDex,String(_player.getDex()));
TweenLite.to(_mc.hp,0.3,{width:_player.getHp()/5< <0});
TweenLite.to(_mc.str,0.3,{width:_player.getStr()*2});
TweenLite.to(_mc.dex,0.3,{width:_player.getDex()*2});
}
function doPK(_p1:Player,_p2:Player){
attack(_p1,_p2);
if(_p2.isAlive()){
setTimeout(doPK,1000,_p2,_p1);
}
}
//攻击函数
function attack(_p1:Player,_p2:Player){
var p1AttackValue:Array=_p1.attack();
gameInfoShow(txtInfoShow,p1AttackValue[1],p1AttackValue[0],_p1);
if(_p1.getRate()>_p2.getRate()){
_p2.setHp(_p2.getHp()-p1AttackValue[0]);
if(_p2.isAlive()){
setTxt(_p2.getBindMC().txtHp,String(_p2.getHp()));
TweenLite.to(_p2.getBindMC().hp,0.3,{width:_p2.getHp()/5< <0});
}else{
setTxt(_p2.getBindMC().txtHp,"死亡");
TweenLite.to(_p2.getBindMC().hp,0.3,{width:0});
txtInfoShow.appendText(_p2.getName()+" 被扁趴下 "+_p1.getName()+" 获得胜利 \n");
btnStart.buttonMode=true;
btnStart.addEventListener (MouseEvent.CLICK,gameStart);
}
}else{
txtInfoShow.appendText("但是 "+_p2.getName()+" 闪开了 \n");
}
}
//文本设置
function setTxt(_txt:TextField,_str:String){
_txt.text=_str;
}
//显示PK实况
function gameInfoShow(_txt:TextField,_style:String,_str:uint,_player:Player){
_txt.appendText(_player.getName()+" "+_style+" 伤害值为 "+_str+"\n");
}
//简单的见车名字输入
function checkPName (playerName:String):Boolean {
if (playerName=="") {
return false;
} else {
return true;
}
}
//去左右空格函数
function trimStr(_str:String){
return StringUtil.trim(_str);
}
[/js]
相对来说主要就是攻击的顺序判断，攻击的命中，还有游戏是否结束的判断。
Source files here:http://dl.getdropbox.com/u/477487/flash/game/namePK.rar

放个豆腐和豆奶的PK结果记录哈：
[html]
比对敏捷值 豆奶 获得优先攻击权
豆奶 使出了砖石星辰拳 伤害值为 122
豆腐 喝下一口酒精喷出一个大火球 伤害值为 82
但是 豆奶 闪开了
豆奶 搬起一块石头砸了过来 伤害值为 111
豆腐 喝下一口酒精喷出一个大火球 伤害值为 91
豆奶 扔出了发着佛光的雅典娜 伤害值为 128
豆腐 不知从哪丢出一陀大便 伤害值为 91
但是 豆奶 闪开了
豆奶 使出了砖石星辰拳 伤害值为 133
豆腐 被扁趴下 豆奶 获得胜利
[/html]

Some Related Posts

• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (4)

public class Player {
//名字
private var _name:String;
//血量值
private var _hp:int;
//力量值，影响攻击力
private var _str:uint;
//敏捷值，影响命中和躲避率
private var _dex:uint;
//幸运值，影响攻击力和命中/闪避率
private var _luck:uint;
//显示状态的MC
private var _bindMC:MovieClip;
//攻击方式
private var _aryAttackStyle:Array=new Array("不知从哪丢出一陀大便","搬起一块石头砸了过来","喝下一口酒精喷出一个大火球","高唱我的菊花为谁开","使出了砖石星辰拳","扔出了发着佛光的雅典娜");
public function Player (__str:String="") {
var strTmp=MD5.hash(__str);
strTmp=str2num(strTmp);
//保证strTmp的长度为10个字符以上
while (strTmp.length<10) {
strTmp+=strTmp;
}
//各属性的赋值和调整
_hp=int(strTmp.substr(0,3));
if (_hp<150) {
_hp+=200;
} else if (500<_hp ) {
_hp=(_hp*0.8)<<0;
}
_str=int(strTmp.substr(3,2));
if (_str<20) {
_str+=20;
} else if (90<_str) {
_str=(_str*0.9)<<0;
}
_dex=int(strTmp.substr(5,2));
if (_dex<20) {
_dex+=20;
} else if (80<_dex) {
_dex=(_dex*0.75)<<0;
}
_luck=int(strTmp.substr(7,2));
_name=__str;
}
public function getName ():String {
return _name;
}
public function setHp (value:int):void {
if(value<0){
value=0;
}
_hp=value;
}
public function getHp ():int {
return _hp;
}
public function getStr ():uint {
return _str;
}
public function getDex ():uint {
return _dex;
}
public function getLuck ():uint {
return _luck;
}
//绑定显示用的MC
public function setBindMC (_mc:MovieClip):void {
_bindMC=_mc;
}
public function getBindMC ():MovieClip {
return _bindMC;
}
//判断是不是还活着
public function isAlive ():Boolean {
if (_hp>0) {
return true;
} else {
return false;
}
}
//攻击函数
public function attack():Array{
var aryAttack:Array=new Array((Math.random()*_str< <0)+_str/5+_luck,_aryAttackStyle[Math.random()*_aryAttackStyle.length<<0]);
return aryAttack;
}
//生成命中和闪避率
public function getRate():Number{
return Math.random()*((_dex+_luck)/100);
}
//获取字符串中数字
public static function str2num (char:String):String {
var pattern:RegExp=/^[-\+]?\d+$/;
var strTemp:String="";
for (var i:uint=0; i var rs:Object=pattern.exec(char.charAt(i));
if (rs==null) {
} else {
strTemp+=char.charAt(i);
}
}
return strTemp;
}
}
}
[/js]
下边是具体的游戏实现部分和源码下载：“GAME-NamePK 基于MD5的名字PK(下)”。

• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (4)

btnInit.addEventListener (MouseEvent.CLICK,showBrain);
btnDownload.addEventListener (MouseEvent.CLICK,downloadIt);

function showBrain (_evt:MouseEvent) {
init ();
}
function init () {
mcBrain.txtName.text=txtInput.text+" 的脑内";
//用户存放名字转换成数字后的字符串
var aryS:Array=new Array();
//先去掉左右空格
var _str:String=StringUtil.trim(txtInput.text);
//MD5转换
_str=MD5.hash(_str);
//获取字符串中的所有数字
_str=StringUtil.str2num(_str);
//取前4位数字
_str=_str.substr(0,4);
//复制到需要的长度，这里设置了60
while (_str.length < 60) {
_str+=_str;
}
//因为不知道怎么对字符串排序，所以塞进数组
for (var i:uint=0; i < _str.length; i++) {
aryS.push (_str.charAt(i));
}
//使用数组的sort来排序，倒序排列
aryS.sort (Array.DESCENDING);
//trace(aryS);
//让放字的mc跑到指定帧显示
for (var j:uint=0; j < 60; j++) {
MovieClip(mcBrain.mcTexts.getChildAt(j)).gotoAndStop (aryS[j]);
}
}
function downloadIt (_evt:MouseEvent) {
//Call the function and pass in the movieclip that you want to encode,
//the quality, and the file name
//As3CoreLib里的函数，从mc制作jpg
createJPG (mcBrain, 90, txtInput.text);
}
function createJPG (m:MovieClip, q:Number, fileName:String) {
var jpgSource:BitmapData = new BitmapData (m.width, m.height);
jpgSource.draw (m);
var jpgEncoder:JPGEncoder = new JPGEncoder(q);
var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);

var header:URLRequestHeader = new URLRequestHeader ("Content-type", "application/octet-stream");

//Make sure to use the correct path to jpg_encoder_download.php
var baseURL:String="http://nwhy.org/nwhy/";//因为这个flash要放别处引用，所以写绝对路径
var jpgURLRequest:URLRequest = new URLRequest (baseURL+"jpg_encoder_download.php?name=" + fileName + ".jpg");
//给php文件发送数据
jpgURLRequest.requestHeaders.push (header);
jpgURLRequest.method = URLRequestMethod.POST;
jpgURLRequest.data = jpgStream;

var jpgURLLoader:URLLoader = new URLLoader();
navigateToURL (jpgURLRequest, "_blank");
}
[/js]
function str2num in utils.StringUtil.as:
[js]
//获取全部数字
public static function str2num (char:String):String {
var pattern:RegExp=/^[-\+]?\d+$/;
var strTemp:String="";
for (var i:uint=0; i var rs:Object=pattern.exec(char.charAt(i));
if (rs==null) {
} else {
strTemp+=char.charAt(i);
}
}
return strTemp;
}
[/js]

Some Related Posts

• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/04/29 -- AS3-图像复制BitmapData.copyPixels() (3)
• 2009/04/23 -- GAME-Quake Live (0)

stage.addEventListener (KeyboardEvent.KEY_DOWN, keyPressedDown);
stage.addEventListener (KeyboardEvent.KEY_UP, keyPressedUp);
stage.addEventListener (Event.ENTER_FRAME, mcMove);
stage.addEventListener (Event.DEACTIVATE, missingStage);//Flash处于非活动状态时调用
//按键时的检测，左上右下分别是37，38，39，40
function keyPressedDown (_evt:KeyboardEvent) {
if (_evt.keyCode == 37) {
leftArrow = true;
} else if (_evt.keyCode == 39) {
rightArrow = true;
} else if (_evt.keyCode == 38) {
upArrow = true;
} else if (_evt.keyCode == 40) {
downArrow = true;
}
}

//松开按键时
function keyPressedUp (_evt:KeyboardEvent) {
if (_evt.keyCode == 37) {
leftArrow = false;
} else if (_evt.keyCode == 39) {
rightArrow = false;
} else if (_evt.keyCode == 38) {
upArrow = false;
} else if (_evt.keyCode == 40) {
downArrow = false;
}
}

//MC的移动部分
function mcMove (_evt:Event) {
//移动的速度
var speed:Number = 8;
if (leftArrow) {
//MC的位置检测，下边相同
if (0<=mc.x) {
mc.x -= speed;
}
}
if (rightArrow) {
if(mc.x<=stageW-mc.width-20){
mc.x += speed;
}
}
if (upArrow) {
if(0<=mc.y){
mc.y -= speed;
}
}
if (downArrow) {
if(mc.y<=stageH-mc.height-20){
mc.y += speed;
}
}
}

//Flash处于非激活状态时
function missingStage (_evt:Event) {
leftArrow = false;
rightArrow = false;
upArrow = false;
downArrow = false;
}
[/js]

Some Related Posts

• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/09/07 -- Flash-一些常用物理公式和AS3的结合应用 (1)
• 2009/08/10 -- AS3-连连看的主要算法 (8)
• 2009/07/28 -- Flash – 说是XXX的模糊理论视觉模型？ (2)
• 2009/07/27 -- Flash-Setter & Getter (0)
• 2009/07/13 -- AS3 Code Optimization一些代码优化的问题 (0)
• 2009/06/25 -- Flash-An Pageflip/Flashbook Engine MegaZine 3 (4)

Some Related Posts

• 2009/07/20 -- AS3-子弹躲避游戏(下) (0)
• 2009/07/17 -- AS3-子弹躲避游戏(上) (1)
• 2009/03/22 -- GAME-NamePK 基于MD5的名字PK(下) (0)
• 2009/03/21 -- GAME-NamePK 基于MD5的名字PK(上) (4)
• 2009/02/24 -- AS3-MC的移动控制 (3)
• 2010/07/29 -- The Evolution of Adobe Flash: From 1996 to 2010 (0)
• 2010/05/13 -- AS3-LightOut (8)
• 2010/04/14 -- AS3-Sokoban推箱子 (11)
• 2010/03/02 -- AS3-类似于机战的角色移动(基于Tile) (4)
• 2009/11/30 -- iPhone-Adobe Flash和Microsoft SliverLight (0)